Word | Macro apici bibliografia

Updated at: 27/10/2016

---

A quanto pare Word non ha tra gli stili di default qualcosa che permetta di avere i riferimenti alla bibliografia come apici nel testo (in particolare se si applica la bibliografia di Nature. Per ovviare al problema, è possibile creare una macro che scorre tutto il documento e applica lo stile "superscript" (apice) a tutti i riferimenti della bibliografia. Per creare la macro i passi da fare sono i seguenti:

• aprire un documento word
• andare nel menu visualizza -> macro
• creare una nuova macro dandole come nome ad esempio "Nature_bibliography"
• una volta cliccato su crea, incollare il seguente codice al posto di quello proposto (fare attenzione al nome della funzione, nel caso in cui si sia scelto un altro nome per la macro)

Sub Nature_bibliography()
'
' Nature_bibliography Macro
'
'
    Dim stylename As String
    Dim exists As Boolean
    Dim s As Style
    Dim fld As Field
                
    stylename = "In-Text Citation"
        
    ' Check if the style already exists.
    exists = False
        
    For Each s In ActiveDocument.Styles
        If s.NameLocal = stylename Then
           exists = True
           Exit For
        End If
    Next
    
    ' If the style did not exist yet, create it.
    If exists = False Then
        Set s = ActiveDocument.Styles.Add(stylename, wdStyleTypeCharacter)
        s.BaseStyle = ActiveDocument.Styles(wdStyleDefaultParagraphFont).BaseStyle
        s.Font.Superscript = True
    End If
    
    ' Now that the style really exists, select it.
    Set s = ActiveDocument.Styles(stylename)
     
    ' Apply the style to all in-text citations.
    For Each fld In ActiveDocument.Fields
        If fld.Type = wdFieldCitation Then
            fld.Select
            Selection.Style = s
        End If
    Next

End Sub

• A questo punto, ogni volta che dobbiamo ri-applicare lo stile, basterà eseguire la macro su tutto il documento